Update CEF

.nix/pkgs/graphite-cef/package.nix

@@ -0,0 +1,45 @@
+{ pkgs, ... }:
+
+let
+  versionFile = builtins.fromJSON (builtins.readFile ./version.json);
+
+  version = versionFile.version;
+  hash = selectSystem versionFile.hashes;
+
+  selectSystem =
+    attrs:
+    attrs.${pkgs.stdenv.hostPlatform.system}
+      or (throw "Unsupported system ${pkgs.stdenv.hostPlatform.system}");
+
+  src = pkgs.fetchurl {
+    url = "https://cef-builds.spotifycdn.com/cef_binary_${version}_${
+      selectSystem {
+        aarch64-linux = "linuxarm64";
+        x86_64-linux = "linux64";
+      }
+    }_minimal.tar.bz2";
+    hash = hash;
+  };
+in
+pkgs.cef-binary.overrideAttrs (finalAttrs: {
+  version = builtins.head (builtins.split "\\+" version);
+  inherit src;
+  postInstall = ''
+    rm -r $out/* $out/.* || true
+    strip ./Release/*.so*
+    mv ./Release/* $out/
+    find "./Resources/locales" -maxdepth 1 -type f ! -name 'en-US.pak' -delete
+    mv ./Resources/* $out/
+    mv ./include $out/
+
+    cat ./CREDITS.html | ${pkgs.xz}/bin/xz -9 -e -c > $out/CREDITS.html.xz
+
+    echo '${
+      builtins.toJSON {
+        type = "minimal";
+        name = builtins.baseNameOf finalAttrs.src.url;
+        sha1 = "";
+      }
+    }' > $out/archive.json
+  '';
+})

.nix/pkgs/graphite-cef/version.json

@@ -0,0 +1,7 @@
+{
+	"version": "146.0.12+g6214c8e+chromium-146.0.7680.179",
+	"hashes": {
+		"aarch64-linux": "sha256-pi3fV3O31YMHcOh+/lnk2gWI6/MaSNAiUgFhD09d7u0=",
+		"x86_64-linux": "sha256-b2HKaSEEXkZsnsBw9bL2JGmKWwRN5l2wu/O1DxfhAgE="
+	}
+}